STICKLINE——畫(huà)柱線(xiàn)，0實(shí)心柱，-1虛線(xiàn)空心柱，1實(shí)線(xiàn)空心柱。后面的輸出會(huì )遮擋住前面的輸出。
MA5:MA(C,5);
畫(huà)柱線(xiàn)1:STICKLINE(C>O,C,O,2,0);
畫(huà)柱線(xiàn)2:STICKLINE(C>O,H,L,0,0),COLORBLUE;
畫(huà)柱線(xiàn)3:STICKLINE(C<O,H,L,1,1);
畫(huà)柱線(xiàn)4:STICKLINE(C<O,C,O,3,-1);
MA10:MA(C,10),COLORGREEN;
DRAWLINE——繪制直線(xiàn)段，0不延長(cháng)，1向右延長(cháng)。PLOYLINE——繪制折線(xiàn)。
畫(huà)直線(xiàn):DRAWLINE(L=LLV(L,10),L,H=HHV(H,10),H,0);
畫(huà)折線(xiàn):PLOYLINE(H=HHV(H,30),H);
均線(xiàn)變色，DRAWNULL——返回無(wú)效值。nodraw——只輸出數值、不輸出線(xiàn)條，不影響公式坐標。LINETHICK0——只輸出數值、不輸出線(xiàn)條，在其它軟件中不影響公式坐標，在通達信中影響公式坐標。
MA1:MA(C,5);
MA2:MA(C,10);
變色:IF(MA1>REF(MA1,1),MA1,DRAWNULL),LINETHICK2,COLORRED;
成交量:V,NODRAW;
MA1:MA(C,5);
MA2:MA(C,10);
變色:IF(MA1>MA2,MA1,DRAWNULL),LINETHICK2,COLORRED;
成交量:V,LINETHICK0;
Winner——獲利盤(pán)，cost——成本分布情況。
獲利盤(pán):WINNER(C)*100;
成本分布:COST(80);
Zig——之字轉向，1最高價(jià)、2最低價(jià)、3收盤(pán)價(jià)。PEAK——波峰價(jià)格，1最高價(jià)、2最低價(jià)、3收盤(pán)價(jià)。TROUGH——波谷價(jià)格，1最高價(jià)、2最低價(jià)、3收盤(pán)價(jià)。
之字轉向:ZIG(3,10);
波峰:PEAK(3,10,1);
波谷:TROUGH(3,10,1);
波峰到現在的周期數——PEAKBARS，波谷到現在的周期數——TROUGHBARS。
波峰到現在周期:PEAKBARS(3,10,1);
波谷到現在周期:TROUGHBARS(3,10,1);
BACKSET——回設，馬后炮。
MA10:MA(C,10);
回設:=BACKSET(C/REF(C,1)>1.09,2);
A:=IF(REF(回設,1)=0 AND 回設=1,1,0);
DRAWICON(A,L*0.98,1);
跨周期引用的公式也具有未來(lái)性質(zhì)。
周J:"KDJ.J#WEEK";
周D:"KDJ.D#WEEK";
金叉:CROSS(周J,周D)*30;
還有一種作弊手法——將公式信號限制在有行情的時(shí)段發(fā)出。
另外一種作弊:O<REF(C,1) AND DATE=1080918;
建議暫時(shí)關(guān)閉本教程，把講義中這一節的內容挨個(gè)復制到你自己的軟件中，按照這一節開(kāi)始時(shí)所講的函數學(xué)習方法復習一遍。
要將自己的思路用公式去表達出來(lái)，首先是確定需要哪些數據，然后觀(guān)察這些數據之間的關(guān)系，再按語(yǔ)句規則的要求用函數去定義觀(guān)察到的關(guān)系。
{K線(xiàn)形態(tài)}
陰線(xiàn):C<O;
陽(yáng)線(xiàn):C>O;
上漲:C>REF(C,1);
下跌:C<REF(C,1);
平盤(pán):C=REF(C,1);
大陽(yáng)線(xiàn):C/REF(C,1)>1.05;
大陰線(xiàn):C/REF(C,1)<0.95;
高開(kāi):O>REF(C,1);
低開(kāi):O<REF(C,1);
高開(kāi)高走:O>REF(C,1) AND C>O;
高開(kāi)低走:O>REF(C,1) AND C<O;
低開(kāi)低走:O<REF(C,1) AND C<O;
低開(kāi)高走:O<REF(C,1) AND C>O;
上跳空:L>REF(H,1);
下跳空:H<REF(L,1);
長(cháng)上影:H/MAX(O,C)>1.03;
長(cháng)下影:MIN(O,C)/L>1.03;
十字星:MAX(O,C)/MIN(O,C)<1.02 AND H/MAX(O,C)>1.01 AND MIN(O,C)/L>1.01;
正T字:O=C AND C=H AND L<H;
倒T字:O=C AND C=L AND H>L;
一字漲停:O=C AND C=H AND L=H AND C>REF(C,1);
一字跌停:O=C AND C=L AND L=H AND C<REF(C,1);
橫盤(pán):HHV(H,20)/LLV(L,20)<1.15;
均線(xiàn)狀況——金叉和死叉。
MA1:MA(C,5);
MA2:MA(C,10);
金叉:CROSS(MA1,MA2);
死叉:CROSS(MA2,MA1);
均線(xiàn)上拐、下拐、將死未死。
MA1:MA(C,5);
MA2:MA(C,10);
上拐:=REF(MA1,1)<REF(MA1,2) AND MA1>REF(MA1,1);
下拐:=REF(MA1,1)>REF(MA1,2) AND MA1<REF(MA1,1);
將死未死:=COUNT(MA1>MA2,5)=5 AND 上拐;
DRAWICON(上拐,MA1*0.98,1);
DRAWICON(下拐,MA1*1.01,2);
DRAWICON(將死未死,MA1*0.96,11);
多頭排列、空頭排列。
MA1:MA(C,5);
MA2:MA(C,10);
MA3:MA(C,20);
多頭排列:=MA1>MA2 AND MA2>MA3;
空頭排列:=MA1<MA2 AND MA2<MA3;
STICKLINE(多頭排列,MA1,MA3,0,0),COLORRED;
STICKLINE(空頭排列,MA1,MA3,0,0),COLORGREEN;
均線(xiàn)粘合、粘合一段時(shí)間。
MA1:MA(C,5);
MA2:MA(C,10);
MA3:MA(C,20);
粘合:=MAX(MAX(MA1,MA2),MA3)/MIN(MIN(MA1,MA2),MA3)<1.02;
粘合一段時(shí)間:=COUNT(粘合,10)=10;
STICKLINE(粘合,MAX(MAX(MA1,MA2),MIN(MIN(MA1,MA2),MA3)),MA3,1,0),COLORRED;
DRAWICON(粘合一段時(shí)間,MA3*0.98,1);
三金叉。
DIF2:"MACD.DIF";
DEA2:"MACD.DEA";
單金叉:CROSS(DIF2,DEA2);
三金叉:(單金叉 AND COUNT(單金叉,10)>=3)*2;
成交量狀況——主要觀(guān)察成交量之間、成交量與均量線(xiàn)之間以及換手率之間的關(guān)系。放量、歷史天量。
放量1:V>REF(V,1)*2;
放量2:V>MA(V,60);
放量3:V*100/FINANCE(7)*100>8;
歷史天量:V=HHV(V,0);
連續放量。
連續放量1:COUNT(V>REF(V,1),5)=5;
連續放量2:(COUNT(V>MA(V,60),5)=5)*2;
連續放量3:(COUNT(V*100/FINANCE(7)*100>8,5)=5)*3;
縮量、歷史地量。
縮量1:V<REF(V,1)*0.5;
縮量2:V<MA(V,60);
縮量3:V*100/FINANCE(7)*100<1;
歷史地量:V=LLV(V,0);
連續縮量。
連續縮量1:COUNT(V<REF(V,1),5)=5;
連續縮量2:(COUNT(V<MA(V,60),5)=5)*2;
連續縮量3:(COUNT(V*100/FINANCE(7)*100<1,5)=5)*3;
籌碼低位密集。
籌碼密集:=(WINNER(C*1.1)-WINNER(C*0.9))*100>50;
相對低位:=(C-COST(0.01))/(COST(99.99)-COST(0.01))*100<10;
低位密集:籌碼密集 AND 相對低位;
第05節 公式轉換
技術(shù)指標轉換為條件選股公式：第一步，確定我們想要的信號；第二步，從下到上尋找信號的關(guān)聯(lián)語(yǔ)句；第三步，刪除無(wú)用語(yǔ)句；第四步，將信號以外的語(yǔ)句變成中間語(yǔ)句，并刪除修飾美化函數；第五步，將公式建立在條件選股類(lèi)別。
{改造前}
LC:=REF(C,1);
RSI1:SMA(MAX(C-LC,0),6,1)/SMA(ABS(C-LC),6,1)*100;
RSV:=(C-LLV(L,9))/(HHV(H,9)-LLV(L,9))*100;
K:SMA(RSV,3,1);
D:SMA(K,3,1);
J:3*K-2*D,LINETHICK2;
MJ:=CROSS(J,D);
MC:=CROSS(D,J);
DRAWICON(MJ,J,1);
DRAWICON(MC,J,2);
{改造后}
RSV:=(C-LLV(L,9))/(HHV(H,9)-LLV(L,9))*100;
K:=SMA(RSV,3,1);
D:=SMA(K,3,1);
J:=3*K-2*D;
CROSS(J,D);
上一頁(yè) [1] [2] [3] [4] 下一頁(yè)
（南方財富網(wǎng)SOUTHMONEY.COM）（責任編輯：張曉軒）